在 Excel 中，SumIf函數(shù)用于單條件求和，它共有三個(gè)參數(shù)，分別為條件區(qū)域、條件和實(shí)際求和區(qū)域；其中實(shí)際求和區(qū)域可以省略，若省略，則把條件區(qū)域作為求和區(qū)域；在條件中可以使用數(shù)學(xué)符號(hào)、通配符和函數(shù)；條件區(qū)域與實(shí)際求和區(qū)域既可以相等也可以不相等。

一般情況下，SumIf函數(shù)只能有一個(gè)條件，但可以用數(shù)組組合條件加Sum函數(shù)實(shí)現(xiàn)SumIf函數(shù)多條件求和；另外，還可以用SumIf函數(shù)求指定數(shù)值范圍的和；此外，還能用SumIf函數(shù)只求到當(dāng)前行的和。

一、Excel SumIf函數(shù)語(yǔ)法

1、表達(dá)式：SUMIF(Range, Criteria, [Sum_Range])

中文表達(dá)式：SUMIF（條件區(qū)域，條件，[求和區(qū)域]）

2、說(shuō)明：

A、如果省略 Sum_Range，則在 Range 中求和；如果有 Sum_Range，則在 Sum_Range 中求和。求和區(qū)域中若有空值、邏輯值和不能轉(zhuǎn)為數(shù)字的文本，它們將被忽略。

B、條件 Criteria 可以是數(shù)字、字符（如“女裝”）、表達(dá)式（如 ">=10"、"<>1"）、單元格引用（A1）、函數(shù)（如 NOW()）；條件中有文本、邏輯值或數(shù)學(xué)符號(hào)都要用雙引號(hào)括號(hào)起來(lái)，單獨(dú)數(shù)字不需用雙引號(hào)括起來(lái)。在條件中，可以使用通配符問(wèn)號(hào)（?）和星號(hào)（*），問(wèn)號(hào)表示一個(gè)字符，星號(hào)表示任意一個(gè)或多個(gè)字符；如果要查找問(wèn)號(hào)或星號(hào)，要使用轉(zhuǎn)義字符~，例如查找問(wèn)號(hào)，需這樣表示 ~?。

C、Sum_Range 與 Range 形狀大小可以不相同，求和的實(shí)際單元格區(qū)域以 Sum_Range 左上角的單元格為起點(diǎn)一直到它右下角的單元格，Range 取與 Sum_Range 對(duì)應(yīng)的單元格，具體見(jiàn)實(shí)例。另外，Sum_Range 與 Range 形狀大小不相同時(shí)，執(zhí)行速度比相同時(shí)慢。

D、當(dāng)SumIf函數(shù)匹配的字符串超過(guò) 255 個(gè)字符時(shí)，將返回值錯(cuò)誤 #VALUE!。

二、Excel SumIf函數(shù)基本使用實(shí)例

（一）省略實(shí)際求和區(qū)域的實(shí)例

1、假如要求服裝銷(xiāo)量大于 700 的所有服裝銷(xiāo)量之和。選中 F11 單元格，把公式 =SUMIF(F2:F10,">700") 復(fù)制到 F11，按回車(chē)，返回求和結(jié)果 3536；操作過(guò)程步驟，如圖1所示：

圖1

2、公式 =SUMIF(F2:F10,">700") 省略了實(shí)際求和區(qū)域 Sum_Range，因此把條件區(qū)域 Range（F2:F10）作為求和區(qū)域。">700" 是條件，意思是把 F2 至 F10 中每個(gè)數(shù)值與 700 比較，如果大于 700，則計(jì)入求和。

提示：條件 ">700" 也可以這樣寫(xiě)：">"&"700"，把大于號(hào)與數(shù)值分開(kāi)寫(xiě)，然后用 & 連接。

（二）有實(shí)際求和區(qū)域的實(shí)例

1、假如要求所有男裝的銷(xiāo)量之和。選中 F11 單元格，把公式 =SUMIF(C2:C10,"男裝",F2:F10) 復(fù)制到 F11，按回車(chē)，返回求和結(jié)果 1879；操作過(guò)程步驟，如圖2所示：

圖2

2、公式 =SUMIF(C2:C10,"男裝",F2:F10) 中，C2:C10 為條件區(qū)域，條件為“男裝”，F(xiàn)2:F10 為實(shí)際求和區(qū)域，意思是：如果 C2:C10 中為“男裝”，則把 F2:F10 與之對(duì)應(yīng)數(shù)值計(jì)入求和；例如 C5 中為“男裝”，則把 F5 計(jì)入求和。

（三）條件帶通配符問(wèn)號(hào)（?）或星號(hào)（*）的實(shí)例

（1）條件帶通配符問(wèn)號(hào)（?）

1、假如要求以“T恤”結(jié)尾并且“T恤”前只有兩個(gè)字的服裝銷(xiāo)量之和。選中 F11 單元格，把公式 =SUMIF(B2:B10,"??T恤",F2:F10) 復(fù)制到 F11，按回車(chē)，返回求和結(jié)果 2844；操作過(guò)程步驟，如圖3所示：

圖3

2、公式 =SUMIF(B2:B10,"??T恤",F2:F10) 中的條件為 "??T恤"，條件中共有兩個(gè)問(wèn)號(hào)，每個(gè)問(wèn)號(hào)表示一個(gè)字符，意思是找出 B2:B10 中由四個(gè)字組成，前兩個(gè)字可以為任意字符，后兩個(gè)字為“T恤”的服裝。

（2）條件帶通配符星號(hào)（*）

1、假如要分別求以“T恤”結(jié)尾、以“粉紅”開(kāi)頭、以“粉”開(kāi)頭且以“襯衫”結(jié)尾的服裝銷(xiāo)量之和。選中 F11 單元格，把公式 =SUMIF(B2:B10,"*T恤",F2:F10) 復(fù)制到 F11，按回車(chē)，返回求和結(jié)果 3482；雙擊 F11 單元格，把公式中的條件改為 "粉紅*"，按回車(chē)，返回求和結(jié)果 1784；再次雙擊 F11，把公式中的條件改為 "粉*襯衫"，按回車(chē)，返回求和結(jié)果 1784；操作過(guò)程步驟，如圖4所示：

圖4

2、公式說(shuō)明：

A、公式 =SUMIF(B2:B10,"*T恤",F2:F10) 中的條件為 "*T恤"，條件中的 * 表示任意字符，可以是一個(gè)也可以是多個(gè)；條件的意思是找出以“T恤”結(jié)果的服裝。

B、公式 =SUMIF(B2:B10,"粉紅*",F2:F10) 中的條件為 "粉紅*"，意思是找出以“粉紅”開(kāi)頭的服裝。

C、公式 =SUMIF(B2:B10,""粉*襯衫",F2:F10) 中的條件為 ""粉*襯衫"，意思是找出以“粉”開(kāi)頭且以“襯衫”結(jié)尾的服裝。

（四）條件中帶函數(shù)的實(shí)例

1、假如要求大于等于服裝平均銷(xiāo)量的所有服裝銷(xiāo)量之和。選中 F11 單元格，把公式 =SUMIF(F2:F10,">="&AVERAGE(F2:F10)) 復(fù)制到 F11，按回車(chē)，返回求和結(jié)果 3536；操作過(guò)程步驟，如圖5所示：

圖5

2、公式 =SUMIF(F2:F10,">="&AVERAGE(F2:F10)) 中的條件為 ">="&AVERAGE(F2:F10)，條件中的 AVERAGE(F2:F10) 用于求服裝的平均銷(xiāo)量。

三、Excel SumIf函數(shù) Sum_Range 與 Range 大小形狀不同的實(shí)例

〈一〉Sum_Range 與 Range 都為一列

（一）Sum_Range 在上，Range 在下

1、選中 F11 單元格，把公式 =SUMIF(C5:C10,"男裝",F2:F5) 復(fù)制到 F11 單元格，按回車(chē)，返回求和結(jié)果 1226；操作過(guò)程步驟，如圖6所示：

圖6

2、公式說(shuō)明：

實(shí)際求和區(qū)域 Sum_Range 為 F2:F5，條件區(qū)域 Range 為 C5:C10，兩個(gè)區(qū)域大小形狀不相同，F(xiàn)2:F5 在上，C5:C10 在下，求和時(shí)把 C5與 F2 對(duì)應(yīng)，C6 與 F3 對(duì)應(yīng)，其它的以此類(lèi)推，相當(dāng)于把 C5:C10 上移；C5:C10 中只有 C5 和 C8 為“男裝”，它們對(duì)應(yīng) F2 和 F5，求和算式為 329 + 897 = 1226。

（二）Sum_Range 在下，Range 在上

1、選中 F11 單元格，把公式 =SUMIF(C2:C6,"男裝",F5:F10) 復(fù)制到 F11，按回車(chē)，返回求和結(jié)果 982，操作過(guò)程步驟，如圖7所示：

圖7

2、公式說(shuō)明：

實(shí)際求和區(qū)域 Sum_Range 為 F5:F10，條件區(qū)域 Range 為 C2:C6，F(xiàn)5:F10 在下，C2:C6 在上，求和時(shí)把 C2 與 F5 對(duì)應(yīng)，C3 與 F6 對(duì)應(yīng)，其它的以此類(lèi)推，相當(dāng)于把 C5:C10 下移；C2:C6 中只有 C5 為“男裝”，它對(duì)應(yīng) F8，因此返回 F8 的數(shù)值 897。

（三）Sum_Range 與 Range 起始位置相同

1、選中 F11 單元格，把公式 =SUMIF(C2:C6,"男裝",F2:F10) 復(fù)制到 F11，按回車(chē)，返回求和結(jié)果 897，操作過(guò)程步驟，如圖8所示：

圖8

2、公式說(shuō)明：

實(shí)際求和區(qū)域 Sum_Range 為 F2:F10，條件區(qū)域 Range 為 C2:C6，兩個(gè)區(qū)域起始位置相同，只是 F2:F10 比 C2:C6 多四個(gè)單元格，求和時(shí)多出的單元格被忽略，而 C2:C6 中只有 C5 為“男裝”，C5 對(duì)應(yīng) F5，因此返回 F5 的數(shù)值 897。

〈二〉Sum_Range 與 Range 都為多列

（一）Sum_Range 在上，Range 在下

1、選中 E10 單元格，把公式 =SUMIF(B5:C9,">700",D2:E6) 復(fù)制到 E10，按回車(chē)，返回求和結(jié)果 582；操作過(guò)程步驟，如圖9所示：

圖9

2、公式說(shuō)明：

實(shí)際求和區(qū)域 Sum_Range 為 D2:E6（在上），條件區(qū)域?yàn)?B5:C9（在下）；它們的對(duì)應(yīng)關(guān)系為：B5 對(duì)應(yīng) D2、C5 對(duì)應(yīng) E2，B6 對(duì)應(yīng) D3、C6 對(duì)應(yīng) E3，其它的以此類(lèi)推，相當(dāng)于把 B5:C9 上移；在 B5:C9 中，只有 B6 和 C9 大于 700，它們分別對(duì)應(yīng) D3 和 F6，求和算式為 253 + 329 = 582。

（二）Sum_Range 在下，Range 在上

1、選中 E10 單元格，把公式 =SUMIF(B2:C6,">700",D4:E8) 復(fù)制到 E10，按回車(chē)，返回求和結(jié)果 876；操作過(guò)程步驟，如圖10所示：

圖10

2、公式說(shuō)明：
實(shí)際求和區(qū)域 Sum_Range 為 D4:E8（在下），條件區(qū)域?yàn)?B2:C6（在上）；它們的對(duì)應(yīng)關(guān)系為：B2 對(duì)應(yīng) D4、C2 對(duì)應(yīng) E4，B3 對(duì)應(yīng) D5、C3 對(duì)應(yīng) E5，其它的以此類(lèi)推，相當(dāng)于把 B2:C6 下移；在 B2:C6 中，只有 B6 大于 700，它對(duì)應(yīng) D8，而 D8 的數(shù)值為 876，所以求和結(jié)果返回 876。

四、Excel SumIf函數(shù)擴(kuò)展使用實(shí)例

（一）SumIf函數(shù)多條件求和

1、假如要求服裝名稱(chēng)以“白色和黑色”開(kāi)頭的所有服裝銷(xiāo)量之和。選中 F11 單元格，把公式 =SUMIF(B2:B10,{"白色*","黑色*"},F2:F10) 復(fù)制到 F11，按回車(chē)，返回求和結(jié)果 1535；雙擊 F11，把公式改為 =SUM(SUMIF(B2:B10,{"白色*","黑色*"},F2:F10))，按回車(chē)，返回求和結(jié)果 3282；操作過(guò)程步驟，如圖11所示：

圖11

2、公式說(shuō)明：

A、=SUMIF(B2:B10,{"白色*","黑色*"},F2:F10) 中的條件為{"白色*","黑色*"}，它是一個(gè)數(shù)組，由兩個(gè)元素組成，是要求服裝名稱(chēng)以“白色和黑色”開(kāi)頭服裝的銷(xiāo)量之和，但公式執(zhí)行后，只返回第一個(gè)元素 "白色*" 作為條件的求和值，第二個(gè)元素的求和值被忽略，因此,只能求出以服裝名稱(chēng)“白色”開(kāi)頭的銷(xiāo)量之和；如果要求滿(mǎn)足兩個(gè)條件的和，Excel2007 及以上版本可以用 SumIfs函數(shù)，Excel2007 以下版本可以用 Sum + SumIf，也就演示的第二個(gè)公式。

B、公式 =SUM(SUMIF(B2:B10,{"白色*","黑色*"},F2:F10)) 用Sum函數(shù)把 SumIF 返回的分別滿(mǎn)足條件 "白色*" 和 "黑色*"的求和結(jié)果再次求和。

（二）SumIf函數(shù)求指范圍的和

1、假如要求銷(xiāo)量在 600 到 800 的所有服裝銷(xiāo)量之和。選中 F11 單元格，把公式 =SUMIF(F2:F10,">=600")-SUMIF(F2:F10,">800") 復(fù)制到 F11，按回車(chē)，返回求和結(jié)果 1403，操作過(guò)程步驟，如圖12所示：

圖12

2、公式 =SUMIF(F2:F10,">=600")-SUMIF(F2:F10,">800") 是把銷(xiāo)量把大于等于 600 的求和結(jié)果減去銷(xiāo)量大于 800 的求和結(jié)果，恰好求出銷(xiāo)量在 600 到 800 之間的所有服裝銷(xiāo)量之和。

（三）SumIf函數(shù)求和到當(dāng)前行

1、假如要求價(jià)格大于 55 的服裝銷(xiāo)量和且只求到當(dāng)前行。選中 G2 單元格，把公式 =SUMIf(E$2:E2,">=55",F$2) 復(fù)制到 G2，按回車(chē)，返回求和結(jié)果 329；再次選中 G2，把鼠標(biāo)移到 G2 左下角的單元格填充柄上，按住左鍵，往下拖，拖到第3行則求和到第3行，拖到第4行則求和第4行；操作過(guò)程步驟，如圖13所示：

圖13

2、公式說(shuō)明：

A、公式 =SUMIF(E$2:E2,">=55",F$2) 中 E$2 表示對(duì)列相對(duì)引用對(duì)行絕對(duì)引用（2 前的 $ 表示絕對(duì)引用），即往下拖時(shí)列和行都不變，往右拖時(shí)，列變行不變；E2 表示對(duì)列和行都是相對(duì)引用，往下拖時(shí)，列不變行變，E2 變自動(dòng)變?yōu)?E3、E4、……。

B、F$2 為實(shí)際求和區(qū)域，它后面其實(shí)省略了 F2，完整的應(yīng)該是 F$2:F2；在引用方面 F$2 與 E$2 是一個(gè)意思，當(dāng)往下拖到 F4 時(shí)，F(xiàn)$2 省略的是 F4。